// julia-fractals vs. glass dices
// povray 3.6
// codeworx.org
// Hans-Jakob Schwer, 21.08.2009


#include "golds.inc"
#include "metals.inc"
#include "finish.inc"   
#include "colors.inc"
#include "textures.inc"
#include "shapes.inc"
#include "metals.inc"
#include "glass.inc"
#include "woods.inc"   

global_settings { max_trace_level 12 }

// consts, used by the julia fractal
#declare ConstC = <-1,0.2,0,0>;  
#declare SLICEDIST = 0.1;

// general objects

camera {
   location <0, 7, -15>
   look_at <0,0,0>
} 

background {
   color rgb <0,0,0>
}

light_source {
   <7,8,9>
   color rgb Red
}

light_source {
   <-9,-6,5>
   color rgb Yellow
}

// the glass-object

#macro wuerfel(size_)  
   intersection
   {
      box
      {
        <-size_,-size_,-size_>,
        < size_, size_, size_>
      }
          
      difference
      {
          sphere
          {
            <0,0,0>
            size_*1.35
            
          }
          
          sphere
          {
            <0,0,0>
            size_*1.20            
          }
      }     
   }
#end 

// union of julia-fractal and a glass dice

#macro jul1()  
union
{  
        object
        {
                julia_fractal 
                {
                   ConstC
                   quaternion
                   sqr
                   max_iteration 12
                   precision 200
                   slice <0,0,0,1> SLICEDIST
                   texture { T_Brass_5C } 
               }
        }

 
        object
        {
                wuerfel(3)
                texture { T_Glass2 } interior {I_Glass caustics 1} 
        }
} 
#end

// the 4 dices
  
object
{
        jul1() 
        scale <1.5,1.5,1.5> 
        rotate <-30,25,10>
        translate <0,0,0 >
}

            
  
object
{
     
        jul1()  
        rotate <30,45,10>
        translate <9.5,4,10 >

}   

object
{
     
        jul1() 
        rotate <30,45,-50>
        translate <-18,-12,15 > 

} 

object
{
     
        jul1() 
        scale <0.1,0.1,0.1>  
        rotate <130,65,70>
        translate <0,4,-12 > 

}   


// the "floor"-object (hollow sphere with glass-texture)
        
object
{  

        difference
        { 
          
                  sphere
                  {
                    <0,-250,0>
                   200
                    
                  }
                  
                  sphere
                  {
                    <0,-250,0>
                   100
                    
                  }
                   
        
        } 

        texture { T_Glass2 } interior {I_Glass caustics 1} 
}